≡ Day 1 of Advent of Code in q

Author - Rory Kemp

Original Problem Statement

--- Day 1: Historian Hysteria ---

The Chief Historian is always present for the big Christmas sleigh launch, but nobody has seen him in months! Last anyone heard, he was visiting locations that are historically significant to the North Pole; a group of Senior Historians has asked you to accompany them as they check the places they think he was most likely to visit.

As each location is checked, they will mark it on their list with a star. They figure the Chief Historian must be in one of the first fifty places they'll look, so in order to save Christmas, you need to help them get fifty stars on their list before Santa takes off on December 25th.

Collect stars by solving puzzles. Two puzzles will be made available on each day in the Advent calendar; the second puzzle is unlocked when you complete the first. Each puzzle grants one star. Good luck!

You haven't even left yet and the group of Elvish Senior Historians has already hit a problem: their list of locations to check is currently empty. Eventually, someone decides that the best place to check first would be the Chief Historian's office.

Upon pouring into the office, everyone confirms that the Chief Historian is indeed nowhere to be found. Instead, the Elves discover an assortment of notes and lists of historically significant locations! This seems to be the planning the Chief Historian was doing before he left. Perhaps these notes can be used to determine which locations to search?

Throughout the Chief's office, the historically significant locations are listed not by name but by a unique number called the location ID. To make sure they don't miss anything, The Historians split into two groups, each searching the office and trying to create their own complete list of location IDs.

There's just one problem: by holding the two lists up side by side (your puzzle input), it quickly becomes clear that the lists aren't very similar. Maybe you can help The Historians reconcile their lists?

For example:

3   4
4   3
2   5
1   3
3   9
3   3

Maybe the lists are only off by a small amount! To find out, pair up the numbers and measure how far apart they are. Pair up the smallest number in the left list with the smallest number in the right list, then the second-smallest left number with the second-smallest right number, and so on.

Within each pair, figure out how far apart the two numbers are; you'll need to add up all of those distances. For example, if you pair up a 3 from the left list with a 7 from the right list, the distance apart is 4; if you pair up a 9 with a 3, the distance apart is 6.

In the example list above, the pairs and distances would be as follows:

To find the total distance between the left list and the right list, add up the distances between all of the pairs you found. In the example above, this is 2 + 1 + 0 + 1 + 2 + 5, a total distance of 11!

Your actual left and right lists contain many location IDs. What is the total distance between your lists?


We are given two columns of numbers, such as the example above. First of all, let's read the input. This can be done with the CSV Reader. 
show i:("J  J"; " ") 0: `1.txt
We are asked to pair up the numbers in order. This requires sorting each. 
show s: asc each i
(`s#1 2 3 3 3 4;`s#3 3 3 4 5 9)
Now it requires taking the (absolute value of) differences, and summing. We can use Apply (.) to subtract one list from the other. 
sum abs (-) . s
11

Part 2:

Part 2 Original Description:

--- Part Two ---

Your analysis only confirmed what everyone feared: the two lists of location IDs are indeed very different.

Or are they?

The Historians can't agree on which group made the mistakes or how to read most of the Chief's handwriting, but in the commotion you notice an interesting detail: a lot of location IDs appear in both lists! Maybe the other numbers aren't location IDs at all but rather misinterpreted handwriting.

This time, you'll need to figure out exactly how often each number from the left list appears in the right list. Calculate a total similarity score by adding up each number in the left list after multiplying it by the number of times that number appears in the right list.

Here are the same example lists again:

3   4
4   3
2   5
1   3
3   9
3   3

For these example lists, here is the process of finding the similarity score:

So, for these example lists, the similarity score at the end of this process is 31 (9 + 4 + 0 + 0 + 9 + 9).

Once again consider your left and right lists. What is their similarity score?

Now, we are required to count occurrences of each number from the left list in the right list. Counting occurrences of items in the right list can be done as follows: 
{count each group y} . i
4 3 5 9!1 3 1 1
Now find the counts of the items in x: 
{(count each group y) x} . i
3 1 0N 0N 3 3
And multiply by the values, and sum. Note that sum ignores nulls. We're also using 0N! which displays values for debugging. 
{sum 0N!x*(count each group y) x} . i
9 4 0N 0N 9 9
31
Alternative solution: Instead of using group, we can construct a table to count occurrences. Here, this uses Each Right (/:). 
{x =/: y} . i 

010000b
100011b
000000b
100011b
000000b
100011b
Then use sum, which sums the rows. 
{sum x =/: y} . i 
3 1 0 0 3 3i
We can see this is the same (except nulls) as the previous solution, using group. All that remains is to multiply by x, and sum. 
{sum x * sum x =/: y} . i 
31

Recap:

The full solution is this.


i:("J  J"; " ") 0: `1.txt
s: asc each i 
sum abs (-) . i / part 1
{sum x*(count each group y) x} . i / part 2

Extra!

It seems on the test data, the first list is unique. The chance of this happening by accident is very small (about 0.38%).

If this is guaranteed, there is a simpler solution.

{x*(count each group y) x} is counting for each (unique, assumed) x how many there are in y, instead we can equivalently select items from y that appear in x. {y inter x}

So in this case, the solution will be 
sum {y inter x} . i
13
This is wrong on the test input, but should be correct on the real one. Upload your input to check!